# &turtlelang;'i käskude seletused

Käesolev osa selgitab &kturtle;'i &turtlelang;i keelt. Esmalt puudutame lühidalt erinevaid instruktsioonide tüüpe. Seejärel selgitame ükshaaval kõiki käske. Sellele järgnevad konteinereid, matemaatikat, küsimusi ja täitmise kontrollereid puudutavad selgitused. Lõpuks aga näitame, kuidas on võimalik luua omaenda käske käsuga learn.

## Instruktsioonide tüübid

Nagu igal keelel, nii on ka &turtlelang;il mitut laadi sõnu ja sümboleid. Järgnevalt selgitame lühidalt nende tüüpide erinevusi.

### Käsud

Just käskudega saab panna kilpkonna või &kturtle;'i midagi tegema. Osa käske eeldab sisendit, osa annab väljundi.

    # forward on käsk, mis vajab sisendit, antud juhul on selleks arv 100:
    forward 100

Täpsemalt kirjeldatakse kõiki käske, mida &kturtle; toetab, siin.

### Arvud

Arvatavasti oled juba koolis õppinud, mis asjad on arvud või mingil muul moel osanud selle välja uurida. &kturtle; kasutab arve üsna sarnaselt sellele, kuidas kasutatakse neid matemaatikas või kas või tavalises kõnepruugis.

Me kasutamine niinimetatud naturaalarve: `0`, `1`, `2`, `3`, `4`, `5` jne. Samuti negatiivseid arve: `-1`, `-2`, `-3` jne. Aga ka murdarve, näiteks: `0.1`, `3,14`, `33,3333`, `-5,05`, `-1,0`.

Arve saab pruukida matemaatilistes arvutustes ja küsimustes. Neid saab lisada ka konteineritesse.

Arvud on koodiredaktoris esile tõstetud tumepunase värviga.

### Stringid

Kõigepealt näide:

    print "Hei, mina olen string."

Selles näites on `print` käsk, `"Hei, mina olen string."` aga string. Stringide alguses ja lõpus seisab `"`, mille järgi &kturtle; tunneb ära, et tegemist on stringiga.

Stringe saab lisada konteineritele, kuid neid ei saa kasutada matemaatilistes arvutustes ega küsimustes.

Stringid on koodiredaktoris esile tõstetud punase värviga.

### Nimed

Programmeerimiskeelt &turtlelang; kasutades on sul võimalik luua uusi asju. Mõnda programmi kirjutades läheb sageli tarvis konteinereid ning mõnigi kord tuleb uute käskude loomiseks tarvitada käsku learn. Luues konteinerit või uut käsku käsuga learn, tuleb määrata ka nimi.

Nime võib valida just sellise, nagu tahad - peaasi, et sel ei oleks juba tähendust. Nii ei saa näiteks anda konteinerile nimeks forward, sest seda kasutab juba sisemine käsk.

    # siin on forward kasutusel konteinerina,
    # aga sel on juba tähendus,
    # mistõttu tulemuseks on viga:
    learn forward {
      print "this is invalid"
    }

    # aga nii läheb küll:
    learn myforward {
      print "this is ok"
    }

Nimed tohivad sisaldada ainult tähti, arve ja alakriipse (_), sealjuures peavad nad algama tähega. Konteinerite nimed peavad algama konteineriprefiksiga ($).

    # forward on siin konteiner,
    # mille alguses seisab prefiks $,
    # nii et ta ei lähe konflikti käsuga forward
    $forward = 20
    print $forward

Arvud on koodiredaktoris esile tõstetud purpurvärviga.

Täpsemalt ja põhjalikumalt ning näidetega tutvu konteineritest ja käsust learn rääkivates osades.

### Omistamised

Omistamiseks kasutatakse sümbolit `=`. Programmeerimiskeeles ei ole ühekordne `=` mitte 'võrdub', vaid pigem 'saab'. Sõnale 'võrdub' vastab paremini sümbol `==`, mis kujutab endast küsimust.

Omistamist kasutatakse peamiselt kahel eesmärgil: (1) sisu lisamiseks konteineritele ja (2) konteineri sisu muutmiseks. Näide:

    $x = 10
    # konteiner x sisaldab nüüd arvu 10
    $W = "Minu vanus on: "
    # konteiner W sisaldab nüüd stringi "Minu vanus on: "
    # järgmine käsk näitab konteinerite 'W' ja 'x' sisu lõuendil
    print $W + $x

Rohkem näiteid leiab konteineritest kõnelevas osas.

### Matemaatikasümbolid

&kturtle; toetab kõiki põhilisi matemaatikasümboleid: liitmine (`+`), lahutamine (`-`), korrutamine (`*`), jagamine (`/`) ja sulud `(` ning `)`.

Põhjalikuma seletuse ja rohkem näiteid leiab matemaatikast kõnelevas osas.

### Küsimused

Me võime esitada lihtsaid küsimusi, mille vastus saab olla kas 'tõene' või 'väär'.

Küsimuste kasutamist selgitab põhjalikult küsimustele pühendatud osa.

### Küsimuste ühendussõnad

Küsimusi saab ühendada niinimetatud ühendussõnadega. Sellisteks sõnadeks on `and`, `or` ja spetsiaalne ühendussõna `not`.

Küsimuste ühendussõnade kasutamist selgitab ühendussõnadele pühendatud osa.

### Kommentaarid

Kommentaarid on sellised read, mille alguses seisab `#`. Näide:

    # see on kommentaar!
    print "see ei ole kommentaar"
    # eelmine rida ei olnud kommentaar, aga järgmine on:
    # print "see ei ole kommentaar"

Kommentaarireaga saame lisada kommentaare koodile iseenda või ka teiste jaoks, kes vähegi seda loevad. Kommentaare kasutatakse (1) programmile väikese kirjelduse lisamiseks, (2) koodiosa toimimise selgitamiseks, kui see võib tunduda veidi segasena, ning (3) selliste koodiridade 'väljakommenteerimiseks', mida tuleks (ajutiselt) ignoreerida (vaata toodud näite viimast rida).

Kommenteeritud read on koodiredaktoris esile tõstetud helehalli värviga.

## Käsud

Just käskudega saab panna kilpkonna või &kturtle;'i midagi tegema. Osa käske eeldab sisendit, osa annab väljundi. Selles osas kirjeldame kõiki käske, mida saab &kturtle;'is kasutada. Pane tähele, et kõik rakenduse poolt pakutavad käsud, mida me siin tutvustame, on koodiredaktoris esile tõstetud sinise värviga, mis aitab neid paremini eristada.

### Kilpkonna liigutamine

Kilpkonna saab lõuendil liigutada mitme käsuga.

forward (fw)

      forward X

  `forward` paneb kilpkonna otse edasi liikuma X piksli võrra. Kui pliiats on sees, jätab kilpkonna ka jälje maha. `forward` asemel võib kasutada lühendit `fw`.

backward (bw)

      backward X

  `backward` paneb kilpkonna otse tagasi liikuma X piksli võrra. Kui pliiats on sees, jätab kilpkonna ka jälje maha. `backward` asemel võib kasutada lühendit `bw`.

turnleft (tl)

      turnleft X

  `turnleft` paneb kilpkonna X kraadi võrra vasakule pöörama. `turnleft` asemel võib kasutada lühendit `tl`.

turnright (tr)

      turnright X

  `turnright` paneb kilpkonna X kraadi võrra paremale pöörama. `turnright` asemel võib kasutada lühendit `tr`.

direction (dir)

      direction X

  `direction` määrab kilpkonna suunaks X kraadi arvestades nullist, see ei ole seotud kilpkonna varasema suunaga. `direction` asemel võib kasutada lühendit `dir`.

center

      center

  `center` sunnib kilpkonna liikuma lõuendi keskpunkti.

go

      go X,Y

  `go` paneb kilpkonna liikuma lõuendi konkreetsesse punkti. See asub X piksli kaugusel lõuendi vasakust servast ja Y piksli kaugusel lõuendi ülaservast.

gox

      gox X

  `gox` paneb kilpkonna samal kõrgusel liikuma X piksli kaugusele lõuendi vasakust servast.

goy

      goy Y

  `goy` paneb kilpkonna samal laiusel (kaugusel vasakust servast) liikuma Y piksli kaugusele lõuendi ülaservast.

Käskudega `go`, `gox`, `goy` ja `center` ei joonista kilpkonn joont, olgu pliiats üleval või all.

### Kus on kilpkonn?

Kilpkonna asukohta lõuendil saab teada kahe käsuga.

getx

  `getx` tagastab pikslite arvu lõuendi vasakust servast kilpkonna asukohani.

gety

  `gety` tagastab pikslite arvu lõuendi ülemisest servast kilpkonna asukohani.

### Kilpkonn pliiatsiga

Kilpkonnal on pliiats, millega ta liikudes joont veab. Pliiatsit saab juhtida mitme käsuga, mida siin tutvustamegi.

penup (pu)

      penup

  `penup` tõstab pliiatsi lõuendilt ja kuni see on üleval, ei tõmba kilpkonn liikudes ühtki joont. Vaata ka `pendown`. `penup` asemel võib kasutada lühendit `pu`.

pendown (pd)

      pendown

  `pendown` surub pliiatsi lõuendi vastu ja kuni see on all, tõmbab kilpkonn liikudes joone. Vaata ka `penup`. `pendown` asemel võib kasutada ka lühendit `pd`.

penwidth (pw)

      penwidth X

  `penwidth` määrab pliiatsi tõmmatava joone laiuseks X pikslit. `penwidth` asemel võib kasutada ka lühendit `pw`.

pencolor (pc)

      pencolor R,G,B

  `pencolor` määrab pliitsi tõmmatava joone värvi. `pencolor` tahab saada sisendina RGB värvikoodi. `pencolor` asemel võib kasutada ka lühendit `pc`.

### Lõuendiga seotud käsud

Lõuendi omadusi saab muuta mitme käsuga.

canvassize (cs)

      canvassize X,Y

  Käsk `canvassize` määrab lõuendi suuruse. Käsu sisendiks on X ja Y, kus X on uue lõuendi laius pikslites ja Y uue lõuendi kõrgus samuti pikslites. `canvassize` asemel võib kasutada lühendit `cs`.

canvascolor (cc)

      canvascolor R,G,B

  Käsk `canvascolor` määrab lõuendi värvi. `canvascolor` tahab saada sisendina RGB värvikoodi. `canvascolor` asemel võib kasutada ka lühendit `cc`.

### Puhastamiskäsud

Kahe käsuga saab lõuendi puhastada sellest, mida sa sinna oled valmis meisterdanud.

clear (ccl)

      clear

  Käsk `clear` puhastab lõuendilt kogu joonistatu. Muud asjad jäävad püsima: kilpkonna asukoht ja nurk, lõuendivärv, kilpkonna nähaolek ja lõuendi suurus.

reset

      reset

  Käsk `reset` puhastab palju rohkem asju kui `clear`. Pärast käsku `reset` on kõik taas selline, nagu &kturtle;'i käivitamisel: kilpkonn on lõuendi keskel, lõuendi värv on valge, kilpkonn hakkab liikudes vedama musta joont ja lõuendi suurus on 400 x 400 pikslit.

### Kilpkonn on sprait

Vaevalt et paljud teavad, mis õieti on sprait, nii et ütleme siis saladuse välja: sprait on väike pilt, mida saab ekraanil liigutada. Täpsemalt vaata sõnastikust mõiste sprait kirjeldust. See tähendab, et meie kilpkonn on sprait!

Toome siin ära kõik käsud, mida saab spraidi puhul kasutada.

[&kturtle;'i praegune versioon toetab spraidina ainult kilpkonna kasutamist. Aga tulevikus võib olla vägagi võimalik, et võid kilpkonna oma soovi kohaselt millegi muuga asendada.]

spriteshow (ss)

      spriteshow

  Käsk `spriteshow` muudab kilpkonna uuesti nähtavaks pärast tema peitmist. `spriteshow` asemel võib kasutada ka lühendit `ss`.

spritehide (sh)

      spritehide

  `spritehide` peidab kilpkonna. Seda on mõtet kasutada siis, kui kilpkonn kohe kuidagi ei taha sinu joonistusele sobida. `spritehide` asemel võib kasutada ka lühendit `sh`.

### Kas kilpkonn oskab ka kirjutada?

Õige vastus: jah, muidugi. Kilpkonn võib kirjutada küll, aga mõistagi pead sina talle ütlema, mida kirjutada.

print

      print X

  `print` annab kilpkonnale käsu midagi lõuendile kirjutada. `print` sisendiks võivad olla nii numbrid kui stringid. Sümbolit + kasutades saab käsuga `print` lasta kirjutada mitmesuguseid numbreid ja stringe. Toome siin väikese näite:

      $year = 2003
      $author = "Cies"
      print $author + " alustas KTurtle'i projekti aastal " + $year + "  ja ta töötab endiselt rõõmuga selle kallal!"

fontsize

      fontsize X

  `fontsize` määrab fondi suuruse, mida `print` kirjutamisel kasutab. `fontsize` sisend peab olema number. Suurus määratakse pikslites.

### Õnnemängukäsk

Üks käsk nii-öelda veeretab sinu eest täringut. Selle nimi on `random` ja sellega saab igasuguseid vahvaid ning ootamatuid asju teha.

random (rnd)

      random X,Y

  `random` on käsk, mis tahab saada sisendit ja annab kohe ka väljundi. Sisendiks on kaks arvu, milles üks (X) määrab minimaalse ja teine (Y) maksimaalse väljundi. Väljund on juhuslik arv, mis on miinimumiga võrdne või suurem ning maksimumiga võrdne või väiksem. Üks väike näide:

      repeat 500 {
        $x = random 1,20
        forward $x
        turnleft 10 - $x
      }

  Käsuga `random` saab oma programmi veidi kaootilisemaks muuta.

### Sisendi- ja tagasisidedialoogid

Dialoog on väike hüpikaken, mis annab teatud tagasisidet või soovib saada mingit sisendit. &kturtle; kasutab dialoogidele kaht käsku: `message` ja `ask`.

message

      message X

  Käsk `message` vajab sisendina stringi. See näitab hüpikdialoogi, mis sisaldab stringi teksti.

      message  "Cies alustas KTurtle'i projekti aastal 2003  ja ta töötab endiselt rõõmuga selle kallal!"

ask

      ask X

  Käsk `ask` vajab sisendina stringi. See näitab hüpikdialoogi, mis sisaldab stringi nagu ka message. Kuid lisaks sellele on dialoogis ka sisendiväli. Selle abil saab kasutaja sisestada arvu või stringi, mis on võimalik salvestada konteinerisse. Näide:

      $in = ask "Kui vana sa oled?"
      $out = 2003 - in
      print "Aastal 2003 olid sa " + $out + " aastat vana."

  Kui kasutaja sulgeb sisenddialoogi või ei sisesta midagi, tühjendatakse vastav konteiner.

## Konteinerid

Konteinerid on tähed või sõnad, mida programmeerija saab tarvitada arvu või teksti mahutamiseks. Arve sisaldavaid konteinereid nimetatakse muutujateks, teksti sisaldavaid stringideks. Konteinereid tunneb ära neile eelneva märgi $ järgi.

Konteinerid, mida ei kasutata, ka ei sisalda midagi. Näide:

    print $N

See ei näita mitte midagi ja annab vaid veateate.

### Muutujad: arvukonteinerid

Toome taas näite:

    $x = 3
    print $x

Esimesel real muudetakse täht `x` muutujaks (numbrikonteineriks). Nagu näed, antakse muutujale `x` väärtuseks 3. Teisel real antakse korraldus see väärtus kirja panna.

Pane tähele, et soovi korral panna kirja x, pidanuks me seda tegema nii:

    print "x"

See oli lihtne, aga võtame kohe raskema näite:

    $A = 2004
    $B = 25
    $C = $A + $B

    # järgmine käsk kirjutab "2029"
    print $C
    backward 30
    # järgmine käsk kirjutab "2004 pluss 25"
    print $A + " plus " + $B
    backward 30
    # järgmine käsk kirjutab  "1979"
    print $A - $B

Esimesel kahel real määratakse muutujate `A` ja `B` väärtuseks 2004 ja 25. Kolmandal real määratakse muutuja `C` väärtuseks `A + B` ehk siis 2029. Ülejäänud osa näitest koosneb kolmest käsust `print`, mida eraldab käsk `backward 30`. `backward 30` on siin selleks, et iga väljund oleks ikka uuel real. Toodud näites on ka näha, et muutujaid saab kasutada matemaatilisteks teheteks.

### Teksti (stringe) sisaldavad konteinerid

Programmeerimiskoodis algab ja lõpeb tavaline tekst enamasti jutumärkidega. Me juba nägime seda:

    print "Hei programmeerija!"

Tavaline tekst on piiratud jutumärkidega. Sellist tavalise teksti juppi nimetamegi stringiks.

Stringe võib salvestada konteinerites täpselt samamoodi nagu arve. Stringid sarnanevad tublisti muutujatega. Suurim erinevus on see, et stringe ei saa kasutada matemaatilistes tehetes ega küsimustes. Näide stringide kasutamise kohta:

    $x = "Tere "
    $name = ask "Palun sisesta oma nimi..."
    print $x + $name + ", kuidas läheb?

Esimesel real määratakse stringi `x` väärtuseks Tere . Teisel real määratakse stringi `name` väärtuseks käsu `ask` väljund. Kolmanda reaga antakse korraldus kirjutada lõuendile kolme stringi kombinatsioon.

Programm palub sul sisestada oma nime. Kui sa näiteks annad oma nimeks Paul, kirjutab programm Tere Paul, kuidas läheb? Pane tähele, et plussmärk (+) on ainus matemaatiline sümbol, mida saab stringide puhul kasutada.

## Kas Kilpkonn ka matemaatikat oskab?

&kturtle;? Ikka oskab. Ta võib liita (+), lahutada (-), korrutada (*) ja jagada (/). Toome siin näite kõigi nende tehetega:

    $a = 20 - 5
    $b = 15 * 2
    $c = 30 / 30
    $d = 1 + 1
    print "a: "+$a+", b: "+$b+", c: "+$c+", d: "+$d

Tead sa ikka, mis on a, b, c ja d väärtus? Pane tähele ka omistamise sümboli `=` kasutamist.

Kui soovid väga lihtsat tehet teha, siis see käib umbes nii:

    print 2004-12

Ja nüüd näide sulgudega:

    print ( ( 20 - 5 ) * 2 / 30 ) + 1

Sulgudes olevad tehted sooritatakse esimestena.

&kturtle; toetab ka keerukamaid matemaatilisi omadusi. Ta tunneb arvu `pii`) ja trigonomeetriafunktsioone, näiteks `sin`, `cos`, `tan`, `arcsin`, `arccos`, `arctan`, samuti ruutjuurt `sqrt` ja eksponentfunktsiooni `exp`.

### Laseme kilpkonnal arve ümardada

Kui vajad arvutustes täisarve, kasuta seda funktsiooni.

round

      round(x)

  `round` ümardab antud arvu lähima täisarvuni.

      print round(10.8)
      forward 20
      print round(10.3)
      forward 20

  Selle koodiga kirjutab kilpkonn arvud 11 ja 10.

## Küsid küsimuse, saad vastuse...

`if` ja `while` on täitmise kontrollerid, mida me käsitleme järgmises osas. Siin kasutame käsku `if` küsimuste selgitamiseks.

### Küsimused

Lihtne näide küsimuse kohta:

    $x = 6
    if $x > 5 {
      print "tere"
    }

Selles näites on küsimuseks `x > 5`. Kui vastus sellele küsimusele on 'tõene', täidetakse looksulgudes olev kood. Küsimused on programmeerimises päris tähtsal kohal ning neid kasutataksegi tihtipeale koos täitmise kontrolleritega, näiteks `if`. Kõiki arve ja muutujaid (arvukonteinereid) saab omavahel võrrelda küsimusi kasutades.

Toome siin ära kõik võimalikud küsimused:

#### Küsimuste tüübid

`a == b` | võrdub | vastus on tõene, kui `a` võrdub `b`
`a != b` | ei võrdu | vastus on tõene, kui `a` ei võrdu `b`
`a > b` | suurem kui | vastus on tõene, kui `a` on suurem kui `b`
`a < b` | väiksem kui | vastus on tõene, kui `a` on väiksem kui `b`
`a >= b` | suurem kui või võrdub | vastus on tõene, kui `a` on suurem kui või võrdub `b`
`a <= b` | väiksem kui või võrdub | vastus on tõene, kui `a` on väiksem kui või võrdub `b`

### Küsimuste ühendussõnad

Küsimusi saab ka üksteisega siduda niinimetatud küsimusliimiga. Sellisel moel saab mitmest küsimusest luua ühe suure küsimuse.

    $a = 1
    $b = 5
    if ($a < $b) and ($b == 5) {
      print "tere"
    }

Selles näites kasutatakse ühendussõna `and` kahe küsimuse 'liimimiseks' (`a < 5`, `b == 5`). Kui üks `and` pooltest on väär, on kogu küsimuse vastus väär, sest ühendussõna `and` korral peab mõlema poole vastus olema tõene, et kogu vastus oleks tõene. Ja ära unusta panna küsimuste ümber sulge!

Põgus ülevaade, millele järgneb põhjalikum seletus:

#### Küsimuste ühendussõnad

`and` | Mõlemad pooled peavad olema 'tõesed', et vastus oleks 'tõene'
`or` | Kui üks pool on 'tõene', on vastus 'tõene'
`not` | Erijuhtum: kasutada ainult ühe küsimusega! Sooritab teisenduse 'tõene' -> 'väär' või 'väär' -> 'tõene'.

#### and

Kui küsimused seotakse kokku sõnaga `and`, peavad mõlemad `and` pooled olema 'tõesed', et kogu tulemus oleks tõene. Näide:

    $a = 1
    $b = 5
    if (($a < 10) and ($b == 5)) and ($a < $b) {
      print "tere"
    }

Toodud näites on kaks ühendatud küsimust koos ühendatud kolmandaga.

#### or

Kui vähemalt üks sõnaga `or` ühendatud küsimustest on 'tõene', on 'tõene' ka tulemus. Näide:

    $a = 1
    $b = 5
    if (($a < 10) or ($b == 10)) or ($a == 0) {
      print "tere"
    }

Toodud näites on kaks ühendatud küsimust koos ühendatud kolmandaga.

#### not

`not` on spetsiaalne ühendussõna, sest see käib korraga ainult ühe küsimuse kohta. `not` sooritab teisenduse 'tõene' -> 'väär' või 'väär' -> 'tõene'. Näide:

    $a = 1
    $b = 5
    if not (($a < 10) and ($b == 5)) {
      print "tere"
    }
    else
    {
      print "ei ütle tere ;-)"
    }

Toodud näites on ühendatud küsimus 'tõene', kuid `not` muudab selle 'vääraks'. Seepärast kirjutatakse lõuendile lõpuks `"ei ütle tere ;-)"`.

## Täitmise kontrollimine

Täitmise kontrollerid lubavad — nagu nimetuski ütleb — kontrollida käsu täitmist.

Täitmise kontrollimise käsud on esile tõstetud tumerohelise rasvase kirjaga. Looksulud, mida väga sageli koos täitmise kontrolleritega pruugitakse, on esile tõstetud musta värviga.

### Kilpkonna ootelejätmine

Kui oled juba natuke &kturtle;'iga harjutanud, paned tähele, et kilpkonn võib päris kiiresti joonistada. See käsk muudab tema tegevuse aga veidi aeglasemaks.

wait

      wait X

  `wait` paneb kilpkonna X sekundiks ootama.

      repeat 36 {
        forward 5
        turnright 10
        wait 0.5
      }

  Selle koodiga joonistatakse ringjoon, aga kilpkonn ootab igal sammul pool sekundit. See jätab mulje nii enam-vähem normaalse kiirusega liikuvast kilpkonnast - vähemalt kilpkonna kohta...

### Tingimuse "kui" (if) täitmine

if

      if küsimus { ... }

  Kood, mis seisab sulgudes, täidetakse ainult siis, kui (`if`) vastus küsimusele on tõene. Loe palun küsimuste kohta täpsemalt küsimusi käsitlevast osast.

      $x = 6
      if $x > 5 {
        print "x on suurem kui viis!"
      }

  Esimesel real määratakse `x` väärtuseks 6. Teisel real esitatakse küsimus `x > 5`. Et vastus sellele küsimusele on tõene, lubab täitmise kontroller `if` looksulgudes oleva koodi täita.

### Vastasel juhul ehk "else"

else

      if küsimus { ... } else { ... }

  Kontrollerit `else` saab kasutada koos kontrolleriga `if`. Kood, mis seisab looksulgudes `else` järel, täidetakse ainult siis, kui vastus esitatud küsimusele on väär.

      reset
      $x = 4
      if $x > 5 {
        print "x on suurem kui viis!"
      }
      else
      {
        print "x on väiksem kui kuus!"
      }

  Küsimus ootab vastuseks, kas `x` on suurem kui 5. Et `x` väärtuseks on esimesel real määratud 4, on vastuseks väär. See tähendab, et täidetakse kood, mis seisab looksulgudes `else` järel.

### Silmus "while"

while

      while küsimus { ... }

  Täitmise kontroller `while` on üsna sarnane kontrolleriga `if`. Nende peamine erinevus seisab selles, et `while` kordab looksulgudes olevat koodi seni, kuni vastus küsimusele on lõpuks väär.

      $x = 1
      while $x < 5 {
        forward 10
        wait 1
        $x = $x + 1
      }

  Esimesel real määratakse `x` väärtuseks 1. Teisel real esitatakse küsimus `x < 5`. Et vastus sellele küsimusele on tõene, alustab täitmise kontroller `while` nurksulgudes oleva koodi täitmist ja teeb seda seni, kuni vastus küsimusele on lõpuks väär. Antud juhul täidetakse nurksulgudes olev kood neli korda, sest iga viienda rea täitmisega suureneb `x` ühe võrra.

### Silmus "repeat"

repeat

      repeat arv { ... }

  Täitmise kontroller `repeat` on üpris sarnane kontrolleriga `while`. Erinevus seisab selles, et `repeat` kordab sulgudes olevat koodi määratud arv kordi.

### Arvestussilmus "for"

for

      for alguspunkt to lõpp-punkt { ... }

  `for` on arvestussilmus, mis teeb midagi teatud arv kordi.

      for $x = 1 to 10 {
        print $x * 7
        forward 15
      }

  Igal looksulgudes oleva koodi täitmisel antakse `x` väärtus ühe võrra suuremana, kuni x võrdub lõpuks 10. Looksulgudes olev kood antud juhul kirjutab tehte '`x` korda 7' tulemuse. Kui programm on töö lõpetanud, on tulemuseks lõuendil ilutsev numbri 7 korrutustabelike.

  Silmuse sammu vaikesuurus on 1, aga kasutada võib mis tahes väärtust.

      for alguspunkt to lõpp-punkt step sammu suurus { ... }

### Silmusest väljumine

break

      break

  Katkestab otsekohe aktiivse silmuse ning annab järje üle vahetult silmuse järel seisvale lausele

### Kilpkonna peatamine

exit

      exit

  Lõpetab koodi täitmise.

## Omaenda käskude loomine käsuga learn

Käsk `learn` on väga eriline, sest selle abil saab luua omaenda käske. Sinu loodud käsk võib kasutada nii sisendit kui anda väljundit. Vaatamegi nüüd, kuidas uus käsk luua.

    learn ringjoon $x {
      repeat 36 {
        forward $x
        turnleft 10
      }
    }

Uus käsk kannab nime `ringjoon`. `ringjoon` kasutab sisendina numbrit, mis määrab ringjoone suuruse. `ringjoon` ei tagasta mingit väljundit. Nüüd võime käsku `ringjoon` kasutada täiesti tavalise käsuna, nagu selles näites:

    learn ringjoon $X {
      repeat 36 {
        forward $X
        turnleft 10
      }
    }

    go 200,200
    ringjoon 20

    go 300,200
    ringjoon 40

Järgmises näites aga loome väljundväärtusega käsu.

    reset

    learn korrutaIseendaga $n {
      $r = $n * $n
      return $r
    }
    $i = ask "Palun sisesta arv ja vajuta OK"
    print $i + " korrutatud iseendaga on: " + korrutaIseendaga $i

Selles näites on uue käsu nimeks `korrutaIseendaga`. Käsu sisend korrutatakse iseendaga ja tagastatakse käsuga `return`. Käsk `return` on meetod omaloodud funktsiooni väljundväärtuse saamiseks.

Käskudel võib olla enam kui üks sisend. Järgmises näites luuakse käsk, mis toob kaasa ristküliku joonistamise.

    learn box $X, $Y {
      forward $Y
      turnright 90
      forward $X
      turnright 90
      forward $Y
      turnright 90
      forward $X
      turnright 90
    }

Nüüd võid käivatada `box 50, 100` ning kilpkonn joonistab lõuendile ristküliku.